Tukukkk

Is there a simple (XSLT?), preferably automated, way to alter an xsd:choice construct in an XSD file to a definition without the choice construct. For example, I get an XSD that contains the following segment:

<xsd:choice minOccurs="1" maxOccurs="1">

   <xsd:element name="ExistingBuild" type="ExistingBuild" nillable="false"/>

   <xsd:element name="NewBuild" type="NewBuild" nillable="false"/>

</xsd:choice>

This XSD needs to be imported in an application that doesn't support the choice construct. I have manually changed the XSD to have the segment defined as follows:

<xsd:element name="ExistingBuild" type="ExistingBuild" nillable="false" minOccurs="0" maxOccurs="1"/>

<xsd:element name="NewBuild" type="NewBuild" nillable="false" minOccurs="0" maxOccurs="1"/>

The resulting XSD can be imported correctly and serves the purpose. So manually I can change this.

However, this XSD will get updated regularly in the future and I would need to manually alter it every time a new version is delivered. To prevent manual errors I am looking to automate this conversion. Is XSLT a possible solution for this, and how would I define such an XSLT solution?

Thanks in advance for any help in this.

It's not that hard to write an XSLT to remove the xsd:choice element

Start with the identity template (which handles the things you don't want to update)

<xsl:template match="@*|node()">

  <xsl:copy>

    <xsl:apply-templates select="@*|node()"/>

  </xsl:copy>

</xsl:template>

Add a template to ignore xsd:choice

<xsl:template match="xsd:choice">

  <xsl:apply-templates />

</xsl:template>

Then add a template to process the child xsd:elements

<xsl:template match="xsd:choice/xsd:element">

  <xsd:element minOccurs="0" maxOccurs="{../@maxOccurs}">

    <xsl:apply-templates select="@*" />

  </xsd:element>

</xsl:template>

Putting this all together gives this...

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

                xmlns:xsd="https://www.w3.org/2001/XMLSchema"

                version="1.0">

  <xsl:output method="xml" indent="yes" />



  <xsl:template match="@*|node()">

    <xsl:copy>

      <xsl:apply-templates select="@*|node()"/>

    </xsl:copy>

  </xsl:template>



  <xsl:template match="xsd:choice">

    <xsl:apply-templates />

  </xsl:template>



  <xsl:template match="xsd:choice/xsd:element">

    <xsd:element minOccurs="0" maxOccurs="{../@maxOccurs}">

      <xsl:apply-templates select="@*" />

    </xsd:element>

  </xsl:template>

</xsl:stylesheet>

See it in action with an imcomplete schema at http://xsltfiddle.liberty-development.net/bFDb2Di