Assume I have an array of the dimensions comb(x, y).

For each element x I need to check if any of the elements y are identical. If so, I will proceed with the next element of x.

If there were 4 elements stored in y for each x the code I would use would be something like this:

For i = 0 To z

    j = 0

    k = j + 1

    l = j + 2

    m = j + 3



    If comb(i, j) <> comb(i, k) And _

    comb(i, j) <> comb(i, l) And _

    comb(i, j) <> comb(i, m) And _

    comb(i, k) <> comb(i, l) And _

    comb(i, k) <> comb(i, m) And _

    comb(i, l) <> comb(i, m) Then



       MsgBox "success"



    End If



 Next i

The thing is, that the dimension of y changes depending on the user input.

Is there a way to automate it for an arbitrary number of elements in y?

You can create three loops that will check each value, but will skip over each other due to the final loop being y + 1 from the second loop.

Dim x As Long, y As Long, z As Long, comb()



For x = LBound(comb, 1) To UBound(comb, 1)

    For y = LBound(comb, 2) To UBound(comb, 2) - 1

        For z = y + 1 To UBound(comb, 2)

            If comb(x, y) = comb(x, z) Then

                msgbox "Match Occurred!"

            End If

        Next z

    Next y

Next x

Essentially, the 2nd loop controls the left side of the equation (the If comb(x, y) = and the 3rd loop controls the right side (the = comb(x, z)).

If desired, to prevent errors where there only may be a single value in the 2nd dimension, you could add an extra If..Then statement, like:

If Lbound(comb, 2) <> Ubound(comb, 2) Then ...

due to the nature of how the third loop adds 1 to y's value, but an error would be raised if there isn't a 1 to add to y.

Visualization

Here is a good visualization to see how this works. This test will print each iteration to the immediate window, you can see that each number is compared with a different number:

Sub test()



    Dim x As Long, y As Long, z As Long, comb(0, 0 To 4)



    For x = LBound(comb, 1) To UBound(comb, 1)

        For y = LBound(comb, 2) To UBound(comb, 2) - 1

            For z = y + 1 To UBound(comb, 2)

                If comb(x, y) = comb(x, z) Then

                    Debug.Print y & "|" & z

                End If

            Next z

        Next y

    Next x



End Sub

Which the immediate window prints:

0|1  

0|2  

0|3  

0|4  

1|2  

1|3  

1|4  

2|3  

2|4  

3|4  

With K.Davis' great help I found the following solution to my problem:

For x = LBound(comb, 1) To UBound(comb, 1)

   For y = LBound(comb, 2) To UBound(comb, 2) - 1

      For z = y + 1 To UBound(comb, 2)

         If comb(x, y) = comb(x, z) Then

            noMatch = True

         End If

      Next z

   Next y



   If noMatch = False Then

      MsgBox x

   End If



   noMatch = False



Next x