Tukukkk

I have 2 text files. File1 has about 1,000 lines and File2 has 20,000 lines. An extract of File1 is as follows:

 /BBC Micro/Thrust

 /Amiga/Alien Breed Special Edition '92

 /Arcade-Vertical/amidar

 /MAME (Advance)/mario

 /Arcade-Vertical/mspacman

 /Sharp X68000/Bubble Bobble (1989)(Dempa)

 /BBC Micro/Chuckie Egg

An extract of File2 is as follows:

 005;005;Arcade-Vertical;;;;;;;;;;;;;;

 Alien Breed Special Edition '92;Alien Breed Special Edition '92;Amiga;;1992;Team 17;Action / Shooter;;;;;;;;;;

 Alien 8 (Japan);Alien 8 (Japan);msx;;1987;Nippon Dexter Co., Ltd.;Action;1;;;;;;;;;

 amidar;amidar;Arcade-Vertical;;;;;;;;;;;;;;

 Bubble Bobble (Japan);Bubble Bobble (Japan);msx2;;;;;;;;;;;;;;

 Buffy the Vampire Slayer - Wrath of the Darkhul King (USA, Europe);Buffy the Vampire Slayer - Wrath of the Darkhul King (USA, Europe);Nintendo Game Boy Advance;;2003;THQ;Action;;;;;;;;;;

 mario;mario;FBA;;;;;;;;;;;;;;

 mspacman;mspacman;Arcade-Vertical;;;;;;;;;;;;;;

 Thrust;Thrust;BBC Micro;;;;;;;;;;;;;;

 Thunder Blade (1988)(U.S. Gold)[128K];Thunder Blade (1988)(U.S. Gold)[128K];ZX Spectrum;;;;;;;;;;;;;;

 Thunder Mario v0.1 (SMB1 Hack);Thunder Mario v0.1 (SMB1 Hack);Nintendo NES Hacks 2;;;;;;;;;;;;;;

 Thrust;Thrust;Vectrex;;;;;;;;;;;;;;

In File3 (the output file), using grep, sed, awk or a bash script, I would like to achieve the following output:

  Thrust;Thrust;BBC Micro;;;;;;;;;;;;;;

  Alien Breed Special Edition '92;Alien Breed Special Edition '92;Amiga;;1992;Team 17;Action / Shooter;;;;;;;;;;

  amidar;amidar;Arcade-Vertical;;;;;;;;;;;;;;

  mspacman;mspacman;Arcade-Vertical;;;;;;;;;;;;;; 

This is similar to a previous question I asked but not the same. I specifically want to avoid the possibility of Thrust;Thrust;Vectrex;;;;;;;;;;;;;; being recorded in File 3.

Using sudo awk -F; 'NR==FNR{a[$1]=$0;next}$1 in a{print a[$1]}', I found that Thrust;Thrust;Vectrex;;;;;;;;;;;;;; was recorded in File 3 instead of Thrust;Thrust;BBC Micro;;;;;;;;;;;;;; (the latter being the output I'm seeking).

Equally, mario;mario;FBA;;;;;;;;;;;;;; won't appear in File3 because it does not match /MAME (Advance)/mario as "MAME (Advance)" doesn't match. That is good. The same for Bubble Bobble (Japan);Bubble Bobble (Japan);msx2;;;;;;;;;;;;;; which doesn't match either "Sharp X68000" or "Bubble Bobble (1989)(Dempa)".

Using AWK and associative array You can use this:

awk '

BEGIN {

  if ( ARGC != 3 ) exit(1);

  FS="/";

  while ( getline < ARGV[2] ) mfggames[$2"/"$3]=1;

  FS=";";

  ARGC=2;

}

mfggames[$3"/"$1]

' file2 file1

Output:

Alien Breed Special Edition '92;Alien Breed Special Edition '92;Amiga;;1992;Team 17;Action / Shooter;;;;;;;;;;

amidar;amidar;Arcade-Vertical;;;;;;;;;;;;;;

mspacman;mspacman;Arcade-Vertical;;;;;;;;;;;;;;

Thrust;Thrust;BBC Micro;;;;;;;;;;;;;;

Sorted per file1 solution (as per comment request):

awk '

BEGIN {

  if ( ARGC != 3 ) exit(1);

  FS="/";

  while ( getline < ARGV[2] ) mfggames[$2"/"$3]=++order;

  FS=";";

  ARGC=2;

}

mfggames[$3"/"$1] { print(mfggames[$3"/"$1] FS $0); }

' file2 file1 | sort -n | cut -d ';' -f 2-

Output:

Thrust;Thrust;BBC Micro;;;;;;;;;;;;;;

Alien Breed Special Edition '92;Alien Breed Special Edition '92;Amiga;;1992;Team 17;Action / Shooter;;;;;;;;;;

amidar;amidar;Arcade-Vertical;;;;;;;;;;;;;;

mspacman;mspacman;Arcade-Vertical;;;;;;;;;;;;;;